#---------------------------------------------------------------------------
# Analisi della molla:
#   -> due fit (allungamento in funzione della masse applicata;
#      periodo di oscillazione in funzione di radice quadrata della massa)
#   -> inferenza di accelerazione di gravità e costante elastica della molla
# GdA, marzo 2010 (riadattamento di modello che girava sotto bugs06) 
#---------------------------------------------------------------------------

model {
   # l Vs m
   for (i in 1:length(l)) {
      mu.l[i] <- c.l + m.l * (m.molla + (Nmin-1 + i) * m.disco);
      l[i] ~dnorm(mu.l[i], tau.l);
   }
   c.l ~ dnorm(0.0, 1.0E-4);
   m.l ~ dnorm(0.0, 1.0E-4);

   tau.l ~ dgamma(1.0E-3, 1.0E-6);
   sigma.l <- 1/sqrt(tau.l);

   # t vs sqrt(m)
   for (i in 1:length(t)) {
      mu.t[i] <- c.t + m.t * sqrt(m.molla + (Nmin-1 + i) * m.disco);
      t[i] ~dnorm(mu.t[i], tau.t);
   }
   c.t ~ dnorm(0.0, 1.0E-4);
   m.t ~ dnorm(0.0, 1.0E-4);

   tau.t ~ dgamma(1.0E-3, 1.0E-5);
   sigma.t <- 1/sqrt(tau.t);

   # k e g
   k <- 4*pi2 / (m.t*m.t)
   g <- m.l * k 
}