#-------------------------------------------------------------------
# Samples of observations with Gaussian errors (UNKNOWN SIGMA)
# affected by offset ('z') and scale ('f') systematics
#   
#  G. D'Agostini, March 2011
#-------------------------------------------------------------------

model {
   #-- sample 1 ------------------
   for (i in 1:length(X1)) {
      X1[i] ~ dnorm(mu1.s, tau.s);
   }
   mu1.s <- f * mu1 + z;
   mu1 ~ dnorm(0.0, 1.0E-6);

   #-- sample 2 ------------------   
   for (i in 1:length(X2)) {
      X2[i] ~ dnorm(mu2.s,tau.s)
   }
   mu2.s <- f * mu2 + z
   mu2 ~ dnorm(0.0, 1.0E-6)

   #-- sample 3 ------------------   
   for (i in 1:length(X3)) {
      X3[i] ~ dnorm(mu3.s,tau.s)
   }
   mu3.s <- f * mu3 + z
   mu3 ~ dnorm(0.0, 1.0E-6)


   #-- common quantities ------------
   tau.s <- f * tau;
   tau ~ dgamma(1.0, 1.0E-4);
   sigma <- 1.0/sqrt(tau);

   f ~ dnorm(1, tau.f);
   tau.f <- 1/(sigma.f*sigma.f)
   z ~ dnorm(0, tau.z);     
   tau.z <- 1/(sigma.z*sigma.z)

   # derived quantities (important for checks: try others):
   Delta.mu.21 <- mu2 - mu1
   Delta.mu.32 <- mu3 - mu2
}